home *** CD-ROM | disk | FTP | other *** search
/ CU Amiga Super CD-ROM 22 / CU Amiga Magazine's Super CD-ROM 22 (1998)(EMAP Images)(GB)[!][issue 1998-05].iso / PowerPC / Datatypes / akSVG / Install < prev   
Encoding:
Text File  |  1997-11-05  |  3.3 KB  |  106 lines
  1. ;$VER: akSVG_Installer 43.100 (16.10.1997) #DOS © Msi Software
  2.  
  3. FAILAT 21
  4.  
  5. ;Check OS version!
  6. c/akT OS 39
  7. IF WARN
  8.    ECHO "You need OS 3.0 or later!"
  9.    ASK "Press return!"
  10.    QUIT
  11. ENDIF
  12.  
  13. ;Display old and new dt version etc!
  14. c/akT >ENV:akver VER classes/Datatypes/akSVG.datatype
  15. c/akT >ENV:akverold VER Sys:Classes/Datatypes/akSVG.datatype
  16. IF NOT WARN
  17.    C:RequestChoice >NIL: "Andreas Ralph Kleinert presents:" "$akver" "Install/Update"
  18. ELSE
  19.    C:RequestChoice >NIL: "Andreas Ralph Kleinert presents:" "$akver*N(old: $akverold)" "Install/Update"
  20. ENDIF
  21. UNSETENV akver
  22. UNSETENV akverold
  23.  
  24. ;Create dt prefs drawer if not found!
  25. IF NOT EXISTS SYS:Prefs/DataTypes
  26.    C:Makedir >NIL: SYS:Prefs/DataTypes
  27.    C:Copy >NIL: prefs/datatypes.info SYS:Prefs/DataTypes.info CLONE
  28. ENDIF
  29.  
  30. ;Move any dtprefs to sys:prefs/datatypes!
  31. IF EXISTS sys:prefs/akSVGprefs
  32.    C:Rename >NIL: sys:prefs/akSVGprefs#? sys:prefs/datatypes
  33. ENDIF
  34.  
  35. ;Create ENV:Datatypes if not found!
  36. IF NOT EXISTS ENV:Datatypes
  37.    C:Makedir >NIL: ENV:Datatypes ENVARC:Datatypes
  38. ENDIF
  39.  
  40. ;Install dtprefs if not found or current one is old!
  41. c/akT CHK prefs/datatypes/akSVGPrefs SYS:prefs/datatypes/akSVGPrefs
  42. IF WARN
  43.    C:Copy >NIL: prefs/datatypes/akSVGPrefs SYS:prefs/datatypes CLONE
  44.    IF NOT EXISTS sys:prefs/datatypes/akSVGPrefs.info
  45.       C:Copy >NIL: prefs/datatypes/akSVGPrefs.info SYS:prefs/datatypes CLONE
  46.    ENDIF
  47. ENDIF
  48.  
  49. ;Install gui if not found or current one is old!
  50. c/akT CHK prefs/datatypes/akSVGPrefs_gui.wizard SYS:prefs/datatypes/akSVGPrefs_gui.wizard
  51. IF WARN
  52.    C:Copy >NIL: prefs/datatypes/akSVGPrefs_gui.wizard SYS:prefs/datatypes CLONE
  53. ENDIF
  54.  
  55. ;Install correct dt!
  56. c/akT CHK classes/datatypes/akSVG.datatype SYS:classes/datatypes/akSVG.datatype
  57. IF WARN
  58.    c/akT CPU 060
  59.    IF NOT WARN
  60.       C:Copy >NIL: classes/datatypes/akSVG.datatype.060 SYS:Classes/datatypes/akSVG.datatype CLONE
  61.    ELSE
  62.       c/akT CPU 040
  63.       IF NOT WARN
  64.          C:Copy >NIL: classes/datatypes/akSVG.datatype.040 SYS:Classes/datatypes/akSVG.datatype CLONE
  65.       ELSE
  66.          c/akT CPU 030
  67.          IF NOT WARN
  68.             C:Copy >NIL: classes/datatypes/akSVG.datatype.030 SYS:Classes/datatypes/akSVG.datatype CLONE
  69.          ELSE
  70.             c/akT CPU 020
  71.             IF NOT WARN
  72.                C:Copy >NIL: classes/datatypes/akSVG.datatype.030 SYS:Classes/datatypes/akSVG.datatype CLONE
  73.             ELSE
  74.                C:Copy >NIL: classes/datatypes/akSVG.datatype SYS:Classes/datatypes/akSVG.datatype CLONE
  75.             ENDIF
  76.          ENDIF
  77.       ENDIF
  78.    ENDIF
  79.  
  80.    ;Move any old dt headers to storage!
  81.    Rename >NIL: SYS:Devs/Datatypes/#?SVG SYS:Storage/Datatypes/
  82.  
  83.    ;Install new dt header!
  84.    C:Copy >NIL: devs/datatypes/SVG DEVS:DataTypes
  85.    IF NOT EXISTS DEVS:DataTypes/SVG.info
  86.       C:Copy >NIL: devs/datatypes/SVG.info DEVS:DataTypes
  87.    ENDIF
  88.  
  89.    ;Change dir to docs!
  90.    CD Docs
  91.  
  92.    ;Show guide and start dtprefs!
  93.    Run >NIL: MultiView akSVG.guide
  94.    Run >NIL: /Prefs/DataTypes/akSVGPrefs
  95.  
  96.    ;Install completed message!
  97.    C:RequestChoice >NIL: "ak Installer" "Install completed!*NPlease reboot the system,*Nto use the new datatype!*N*NIf this is the first time you install,*Nyou do not need to reboot!" "Ok"
  98.    C:AddDataTypes >NIL: REFRESH
  99. ELSE
  100.    ;Install not needed message!
  101.    C:RequestChoice >NIL: "ak Installer" "Install not needed!*NYou have the same or a higher version!" "Ok"
  102. ENDIF
  103.  
  104. ;Clean up memory/free resources!
  105. C:Avail >NIL: FLUSH
  106.